puremvc-haxe-demo-feathersui-todomvc

Author: joshtynjala

puremvc-haxe-demo-feathersui-todomvc/LICENSE

@@ -0,0 +1,12 @@
+- PureMVC TodoMVC Demo for Haxe and Feathers UI - Copyright © 2022 Bowler Hat LLC
+- Original TodoMVC Project - Copyright © Addy Osmani, Sindre Sorhus
+- PureMVC - Copyright © 2006-2012 Futurescale, Inc.
+- All rights reserved.
+
+- Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:
+
+  - Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
+  - Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
+  - Neither the name of Futurescale, Inc., PureMVC.org, nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

puremvc-haxe-demo-feathersui-todomvc/README.md

@@ -0,0 +1,34 @@
+# PureMVC Haxe Feathers UI TodoMVC
+
+This example app demonstrates how to create [TodoMVC](https://todomvc.com) using [PureMVC](http://puremvc.org/) and [Feathers UI](https://feathersui.com/).
+
+## Live demo
+
+A build of the [_puremvc-haxe-demo-feathersui-todomvc_ sample](https://feathersui.com/samples/haxe-openfl/puremvc/puremvc-haxe-demo-feathersui-todomvc/) is hosted on the Feathers UI website, and it may be viewed in any modern web browser.
+
+## Run locally
+
+This project includes an [_project.xml_](https://lime.software/docs/project-files/xml-format/) file that configures all options for [OpenFL](https://openfl.org/). This file makes it easy to build from the command line, and many IDEs can parse this file to configure a Haxe project to use OpenFL.
+
+### Prerequisites
+
+- [Install Haxe 4.0.0 or newer](https://haxe.org/download/)
+- [Install Feathers UI from Haxelib](https://feathersui.com/learn/haxe-openfl/installation/)
+
+### Command Line
+
+Run the [**openfl**](https://www.openfl.org/learn/haxelib/docs/tools/) tool in your terminal:
+
+```sh
+haxelib run openfl test html5
+```
+
+In addition to `html5`, other supported targets include `windows`, `mac`, `linux`, `android`, and `ios`. See [Lime Command Line Tools: Basic Commands](https://lime.software/docs/command-line-tools/basic-commands/) for complete details about the available commands.
+
+### Editors and IDEs
+
+Check out the following tutorials for creating Feathers UI projects in popular development environments:
+
+- [HaxeDevelop](https://feathersui.com/learn/haxe-openfl/haxedevelop/)
+- [Moonshine IDE](https://feathersui.com/learn/haxe-openfl/moonshine-ide/)
+- [Visual Studio Code](https://feathersui.com/learn/haxe-openfl/visual-studio-code/)

puremvc-haxe-demo-feathersui-todomvc/assets/icons/feathersui-icon.svg

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="utf-8"?>
+<project>
+	<meta title="TodoMVC" package="com.feathersui.samples.puremvc.TodoMVC" version="1.0.0" company="Bowler Hat LLC"/>
+	<meta title="PureMVC Haxe Feathers UI TodoMVC Demo — Feathers UI Samples" if="html5"/>
+	<app main="TodoMVC" file="TodoMVC"/>
+
+	<window allow-high-dpi="true"/>
+	<window fps="60"/>
+	<window fps="0" if="html5"/>
+	
+	<source path="src"/>
+	
+	<haxelib name="openfl"/>
+	<haxelib name="actuate"/>
+	<haxelib name="feathersui"/>
+	<haxelib name="puremvc-standard"/>
+
+	<icon path="assets/icons/feathersui-icon.svg"/>
+</project>

puremvc-haxe-demo-feathersui-todomvc/project.xml

@@ -0,0 +1,29 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+import feathers.controls.Application;
+import feathers.events.FeathersEvent;
+import feathers.style.Theme;
+import org.puremvc.haxe.demos.feathersui.todomvc.ApplicationFacade;
+import org.puremvc.haxe.demos.feathersui.todomvc.theme.TodoTheme;
+import org.puremvc.haxe.demos.feathersui.todomvc.view.components.MainView;
+
+class TodoMVC extends Application {
+	public function new() {
+		Theme.setTheme(new TodoTheme());
+		super();
+		this.addEventListener(FeathersEvent.CREATION_COMPLETE, event -> facade.startup(this));
+	}
+
+	public var mainView:MainView;
+
+	private var facade = ApplicationFacade.getInstance();
+
+	override private function initialize():Void {
+		super.initialize();
+		this.mainView = new MainView();
+		this.addChild(this.mainView);
+	}
+}

puremvc-haxe-demo-feathersui-todomvc/src/TodoMVC.hx

@@ -0,0 +1,57 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+package org.puremvc.haxe.demos.feathersui.todomvc;
+
+import org.puremvc.haxe.demos.feathersui.todomvc.controller.ApplicationStartupCommand;
+import org.puremvc.haxe.patterns.facade.Facade;
+
+/**
+	A concrete `Facade` for the `TodoMVC` application.
+
+	The main job of the `ApplicationFacade` is to act as a single 
+	place for mediators, proxies and commands to access and communicate
+	with each other without having to interact with the Model, View, and
+	Controller classes directly. All this capability it inherits from 
+	the PureMVC Facade class.
+
+	This concrete Facade subclass is also a central place to define 
+	notification constants which will be shared among commands, proxies and
+	mediators, as well as initializing the controller with Command to 
+	Notification mappings.
+**/
+class ApplicationFacade extends Facade {
+	// Notification name constants
+	public static final STARTUP = "startup";
+
+	public function new() {
+		super();
+	}
+
+	/**
+		Singleton ApplicationFacade Factory Method
+	**/
+	public static function getInstance():ApplicationFacade {
+		if (Facade.instance == null) {
+			Facade.instance = new ApplicationFacade();
+		}
+		return cast(Facade.instance, ApplicationFacade);
+	}
+
+	/**
+		Register Commands with the Controller 
+	**/
+	override private function initializeController():Void {
+		super.initializeController();
+		registerCommand(STARTUP, ApplicationStartupCommand);
+	}
+
+	/**
+		Start the application
+	**/
+	public function startup(app:TodoMVC):Void {
+		sendNotification(STARTUP, app);
+	}
+}

puremvc-haxe-demo-feathersui-todomvc/src/org/puremvc/haxe/demos/feathersui/todomvc/ApplicationFacade.hx

@@ -0,0 +1,39 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+package org.puremvc.haxe.demos.feathersui.todomvc.controller;
+
+import org.puremvc.haxe.patterns.command.MacroCommand;
+
+/**
+	A MacroCommand executed when the application starts.
+
+	@see org.puremvc.demos.feathersui.appskeleton.controller.ModelPrepCommand
+	@see org.puremvc.demos.feathersui.appskeleton.controller.ViewPrepCommand
+ */
+class ApplicationStartupCommand extends MacroCommand {
+	/**
+		Initialize the MacroCommand by adding its SubCommands.
+
+		Since we built the UI using an MXML `Application` tag, those
+		components are created first. The top level `Application`
+		then initialized the `ApplicationFacade`, which in turn initialized 
+		the `Controller`, registering Commands. Then the 
+		`Application` sent the `APP_STARTUP`
+		Notification, leading to this `MacroCommand`'s execution.
+
+		It is important for us to create and register Proxys with the Model 
+		prior to creating and registering Mediators with the View, since 
+		availability of Model data is often essential to the proper 
+		initialization of the View.
+
+		So, `ApplicationStartupCommand` first executes 
+		`ModelPrepCommand` followed by `ViewPrepCommand`
+	**/
+	override private function initializeMacroCommand():Void {
+		addSubCommand(ModelPrepCommand);
+		addSubCommand(ViewPrepCommand);
+	}
+}

puremvc-haxe-demo-feathersui-todomvc/src/org/puremvc/haxe/demos/feathersui/todomvc/controller/ApplicationStartupCommand.hx

@@ -0,0 +1,19 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+package org.puremvc.haxe.demos.feathersui.todomvc.controller;
+
+import org.puremvc.haxe.demos.feathersui.todomvc.model.TodosProxy;
+import org.puremvc.haxe.interfaces.INotification;
+import org.puremvc.haxe.patterns.command.SimpleCommand;
+
+/**
+	Create and register `Proxy`s with the `Model`.
+**/
+class ModelPrepCommand extends SimpleCommand {
+	override public function execute(note:INotification):Void {
+		facade.registerProxy(new TodosProxy());
+	}
+}

puremvc-haxe-demo-feathersui-todomvc/src/org/puremvc/haxe/demos/feathersui/todomvc/controller/ModelPrepCommand.hx

@@ -0,0 +1,26 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+package org.puremvc.haxe.demos.feathersui.todomvc.controller;
+
+import org.puremvc.haxe.demos.feathersui.todomvc.view.ApplicationMediator;
+import org.puremvc.haxe.interfaces.INotification;
+import org.puremvc.haxe.patterns.command.SimpleCommand;
+
+/**
+	Prepare the View for use.
+
+	The `Notification` was sent by the `Application`,
+	and a reference to that view component was passed on the note body.
+	The `ApplicationMediator` will be created and registered using this
+	reference. The `ApplicationMediator` will then register 
+	all the `Mediator`s for the components it created.
+**/
+class ViewPrepCommand extends SimpleCommand {
+	override public function execute(note:INotification):Void {
+		// Register the ApplicationMediator
+		facade.registerMediator(new ApplicationMediator(cast(note.getBody(), TodoMVC)));
+	}
+}

puremvc-haxe-demo-feathersui-todomvc/src/org/puremvc/haxe/demos/feathersui/todomvc/controller/ViewPrepCommand.hx

@@ -0,0 +1,80 @@
+/*
+	PureMVC Haxe Demo - Feathers UI TodoMVC
+	Copyright (c) 2022 Bowler Hat LLC
+ */
+
+package org.puremvc.haxe.demos.feathersui.todomvc.model;
+
+import feathers.data.ArrayCollection;
+import org.puremvc.haxe.demos.feathersui.todomvc.model.vo.TodoItem;
+import org.puremvc.haxe.interfaces.IProxy;
+import org.puremvc.haxe.patterns.proxy.Proxy;
+
+class TodosProxy extends Proxy implements IProxy {
+	public static final NAME = "TodosProxy"; // Proxy name
+
+	public function new(data:Any = null) {
+		super(NAME);
+	}
+
+	public var todosCollection = new ArrayCollection<TodoItem>();
+
+	public function addTodoItem(item:TodoItem):Void {
+		this.todosCollection.add(item);
+	}
+
+	public function removeTodoItem(item:TodoItem):Void {
+		this.todosCollection.remove(item);
+	}
+
+	public function editTodoItem(item:TodoItem, newText:String):Void {
+		item.text = newText;
+		this.todosCollection.updateAt(this.todosCollection.indexOf(item));
+	}
+
+	public function toggleCompleted(item:TodoItem):Void {
+		item.completed = !item.completed;
+		this.todosCollection.updateAt(this.todosCollection.indexOf(item));
+	}
+
+	public function clearCompleted():Void {
+		var savedFilterFunction = this.todosCollection.filterFunction;
+		this.todosCollection.filterFunction = null;
+		var i = this.todosCollection.length - 1;
+		while (i >= 0) {
+			var todoItem = this.todosCollection.get(i);
+			if (todoItem.completed) {
+				this.todosCollection.removeAt(i);
+			}
+			i--;
+		}
+		this.todosCollection.filterFunction = savedFilterFunction;
+	}
+
+	public function refreshSelectAll(select:Bool):Void {
+		for (todoItem in this.todosCollection.array) {
+			todoItem.completed = select;
+		}
+		this.todosCollection.updateAll();
+	}
+
+	public function filterAll():Void {
+		this.todosCollection.filterFunction = null;
+	}
+
+	public function filterActive():Void {
+		this.todosCollection.filterFunction = activeFilterFunction;
+	}
+
+	public function filterCompleted():Void {
+		this.todosCollection.filterFunction = completedFilterFunction;
+	}
+
+	private function activeFilterFunction(item:TodoItem):Bool {
+		return !item.completed;
+	}
+
+	private function completedFilterFunction(item:TodoItem):Bool {
+		return item.completed;
+	}
+}