puremvc-haxe-demo-hello-openfl

Author: joshtynjala

puremvc-haxe-demo-hello-openfl/LICENSE

@@ -0,0 +1,12 @@
+* PureMVC Haxe Demo - Hello OpenFL - Copyright © 2022 Bowler Hat LLC
+* PureMVC AS3 / Flash Demo - HelloFlash - Copyright © 2008, Cliff Hall
+* PureMVC - Copyright(c) 2007-2008 Futurescale, Inc.
+All rights reserved.
+
+* Redistribution and use in source and binary forms, with or without modification, are permitted provided that the following conditions are met:
+
+  * Redistributions of source code must retain the above copyright notice, this list of conditions and the following disclaimer.
+  * Redistributions in binary form must reproduce the above copyright notice, this list of conditions and the following disclaimer in the documentation and/or other materials provided with the distribution.
+  * Neither the name of Futurescale, Inc., PureMVC.org, nor the names of its contributors may be used to endorse or promote products derived from this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

puremvc-haxe-demo-hello-openfl/README.md

@@ -0,0 +1,55 @@
+# PureMVC Haxe Hello OpenFL
+
+This example app demonstrates how to use [PureMVC](http://puremvc.org/) within an [OpenFL](https://openfl.org/) project. A lonely little blue box appears, moving in a grey room. Interact with it.
+
+Based on [PureMVC ActionScript 3 Demo: HelloFlash (Flash)](https://github.com/PureMVC/puremvc-as3-demo-flash-helloflash)
+
+## Interaction
+
+A lonely little blue box appears, moving in a grey room. Interact with it.
+
+- When it hits a wall it changes direction and shrinks.
+- If you grab it and drag it around, diffrently colored boxes trail out going the opposite of the direction you drag.
+- The colors are from a short palette of about 5 colors and they cycle.
+- If you roll your mouse-wheel all the boxes scale up or down in size depending on the direction you scroll it. (Mac users use the two-finger downswipe to scale up and two-finger upswipe to scale down)
+- When the boxes are all tiny, its hard to grab them, so you might scale them all up.
+- Catch one and hold on to it. Allow the others to decay in size a bit by bouncing off the walls. Then drag around to emit some, let them decay, etc.
+- Scale them up until they all look like a jigging mass of Jello™. Then scroll farther, most wrap around and become small, but some stay large. Let them decay.
+
+## Techniques Illustrated
+
+- Starting the application via the ApplicationFacade
+- Sending a Notification to trigger a Startup Command
+- Initializing the Model and View from a Command
+- Dynamically created View Components and Mediators with unique instance names
+- View components communicating with their Mediators
+- Mediators communicating with a Proxy
+- Use of a Proxy to hold Model data
+- Mediators communicating with other Mediators via Notification
+
+## Live demo
+
+A build of the [_puremvc-haxe-demo-hello-openfl_ sample](https://feathersui.com/samples/haxe-openfl/puremvc/puremvc-haxe-demo-hello-openfl/) is hosted on the Feathers UI website, and it may be viewed in any modern web browser.
+
+## Run locally
+
+This project includes an [_project.xml_](https://lime.software/docs/project-files/xml-format/) file that configures all options for [OpenFL](https://openfl.org/). This file makes it easy to build from the command line, and many IDEs can parse this file to configure a Haxe project to use OpenFL.
+
+### Prerequisites
+
+- [Install Haxe 4.0.0 or newer](https://haxe.org/download/)
+- Install OpenFL from Haxelib
+  ```sh
+  haxelib install openfl
+  haxelib run openfl setup
+  ```
+
+### Command Line
+
+Run the [**openfl**](https://www.openfl.org/learn/haxelib/docs/tools/) tool in your terminal:
+
+```sh
+haxelib run openfl test html5
+```
+
+In addition to `html5`, other supported targets include `windows`, `mac`, `linux`, `android`, and `ios`. See [Lime Command Line Tools: Basic Commands](https://lime.software/docs/command-line-tools/basic-commands/) for complete details about the available commands.

puremvc-haxe-demo-hello-openfl/assets/icons/feathersui-icon.svg

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="utf-8"?>
+<project>
+	<meta title="Hello OpenFL" package="com.feathersui.samples.puremvc.HelloOpenFL" version="1.0.0" company="Bowler Hat LLC"/>
+	<meta title="PureMVC Haxe Hello OpenFL Demo — Feathers UI Samples" if="html5"/>
+	<app main="HelloOpenFL" file="HelloOpenFL"/>
+
+	<window allow-high-dpi="true"/>
+	<window fps="60"/>
+	<window fps="0" if="html5"/>
+	
+	<source path="src"/>
+	
+	<haxelib name="openfl"/>
+	<haxelib name="puremvc-standard"/>
+
+	<icon path="assets/icons/feathersui-icon.svg"/>
+</project>

puremvc-haxe-demo-hello-openfl/project.xml

@@ -0,0 +1,17 @@
+/*
+	PureMVC Haxe Demo - Hello OpenFL
+	Copyright (c) 2022 Bowler Hat LLC
+	PureMVC AS3 / Flash Demo - HelloFlash
+	By Cliff Hall <clifford.hall@puremvc.org>
+	Copyright(c) 2007-08, Some rights reserved.
+ */
+
+import openfl.display.Sprite;
+import org.puremvc.haxe.demos.openfl.helloopenfl.ApplicationFacade;
+
+class HelloOpenFL extends Sprite {
+	public function new() {
+		super();
+		ApplicationFacade.getInstance().startup(this.stage);
+	}
+}

puremvc-haxe-demo-hello-openfl/src/HelloOpenFL.hx

@@ -0,0 +1,64 @@
+/*
+	PureMVC Haxe Demo - Hello OpenFL
+	Copyright (c) 2022 Bowler Hat LLC
+	PureMVC AS3 / Flash Demo - HelloFlash
+	By Cliff Hall <clifford.hall@puremvc.org>
+	Copyright(c) 2007-08, Some rights reserved.
+ */
+
+package org.puremvc.haxe.demos.openfl.helloopenfl;
+
+import openfl.display.Stage;
+import org.puremvc.haxe.demos.openfl.helloopenfl.controller.StartupCommand;
+import org.puremvc.haxe.patterns.facade.Facade;
+
+/**
+	A concrete `Facade` for the `HelloOpenFL` application.
+
+	The main job of the `ApplicationFacade` is to act as a single 
+	place for mediators, proxies and commands to access and communicate
+	with each other without having to interact with the Model, View, and
+	Controller classes directly. All this capability it inherits from 
+	the PureMVC Facade class.
+
+	This concrete Facade subclass is also a central place to define 
+	notification constants which will be shared among commands, proxies and
+	mediators, as well as initializing the controller with Command to 
+	Notification mappings.
+**/
+class ApplicationFacade extends Facade {
+	// Notification name constants
+	public static final STARTUP = "startup";
+	public static final STAGE_ADD_SPRITE = "stageAddSprite";
+	public static final SPRITE_SCALE = "spriteScale";
+	public static final SPRITE_DROP = "spriteDrop";
+
+	public function new() {
+		super();
+	}
+
+	/**
+		Singleton ApplicationFacade Factory Method
+	**/
+	public static function getInstance():ApplicationFacade {
+		if (Facade.instance == null) {
+			Facade.instance = new ApplicationFacade();
+		}
+		return cast(Facade.instance, ApplicationFacade);
+	}
+
+	/**
+		Register Commands with the Controller 
+	**/
+	override private function initializeController():Void {
+		super.initializeController();
+		registerCommand(STARTUP, StartupCommand);
+	}
+
+	/**
+		Start the application
+	**/
+	public function startup(stage:Stage):Void {
+		sendNotification(STARTUP, stage);
+	}
+}

puremvc-haxe-demo-hello-openfl/src/org/puremvc/haxe/demos/openfl/helloopenfl/ApplicationFacade.hx

@@ -0,0 +1,34 @@
+/*
+	PureMVC Haxe Demo - Hello OpenFL
+	Copyright (c) 2022 Bowler Hat LLC
+	PureMVC AS3 / Flash Demo - HelloFlash
+	By Cliff Hall <clifford.hall@puremvc.org>
+	Copyright(c) 2007-08, Some rights reserved.
+ */
+
+package org.puremvc.haxe.demos.openfl.helloopenfl.controller;
+
+import openfl.display.Stage;
+import org.puremvc.haxe.demos.openfl.helloopenfl.model.SpriteDataProxy;
+import org.puremvc.haxe.demos.openfl.helloopenfl.view.StageMediator;
+import org.puremvc.haxe.interfaces.ICommand;
+import org.puremvc.haxe.interfaces.INotification;
+import org.puremvc.haxe.patterns.command.SimpleCommand;
+
+/**
+	A command executed when the application starts.
+ */
+class StartupCommand extends SimpleCommand implements ICommand {
+	/**
+		Register the Proxies and Mediators.
+
+		Get the View Components for the Mediators from the app,
+		which passed a reference to itself on the notification.
+	**/
+	override public function execute(note:INotification):Void {
+		facade.registerProxy(new SpriteDataProxy());
+		var stage = cast(note.getBody(), Stage);
+		facade.registerMediator(new StageMediator(stage));
+		sendNotification(ApplicationFacade.STAGE_ADD_SPRITE);
+	}
+}

puremvc-haxe-demo-hello-openfl/src/org/puremvc/haxe/demos/openfl/helloopenfl/controller/StartupCommand.hx

@@ -0,0 +1,65 @@
+/*
+	PureMVC Haxe Demo - Hello OpenFL
+	Copyright (c) 2022 Bowler Hat LLC
+	PureMVC AS3 / Flash Demo - HelloFlash
+	By Cliff Hall <clifford.hall@puremvc.org>
+	Copyright(c) 2007-08, Some rights reserved.
+ */
+
+package org.puremvc.haxe.demos.openfl.helloopenfl.model;
+
+import org.puremvc.haxe.patterns.proxy.Proxy;
+
+class SpriteDataProxy extends Proxy {
+	public static final NAME = "SpriteDataProxy"; // Proxy name
+
+	public function new() {
+		super(NAME, 0);
+		palette = [blue, red, yellow, green, cyan];
+	}
+
+	private var palette:Array<UInt>;
+	private var red:UInt = 0xFF0000;
+	private var green:UInt = 0x00FF00;
+	private var blue:UInt = 0x0000FF;
+	private var yellow:UInt = 0xFFFF00;
+	private var cyan:UInt = 0x00FFFF;
+
+	public function nextSpriteColor(startColor:UInt):UInt {
+		// identify color index
+		var index = 0;
+		for (j in 0...palette.length) {
+			index = j;
+			if (startColor == palette[index])
+				break;
+		}
+
+		// select the next color in the palette
+		index = (index == palette.length - 1) ? 0 : index + 1;
+		// return startColor;
+		return palette[index];
+	}
+
+	/**
+	 * Get the next Sprite ID
+	 */
+	public var nextSpriteID(get, never):String;
+
+	private function get_nextSpriteID():String {
+		return "sprite" + spriteCount++;
+	}
+
+	/**
+	 * Get the number of sprites
+	 */
+	public var spriteCount(get, set):Int;
+
+	private function get_spriteCount():Int {
+		return (data : Int);
+	}
+
+	private function set_spriteCount(count:Int):Int {
+		data = count;
+		return data;
+	}
+}

puremvc-haxe-demo-hello-openfl/src/org/puremvc/haxe/demos/openfl/helloopenfl/model/SpriteDataProxy.hx

@@ -0,0 +1,108 @@
+/*
+	PureMVC Haxe Demo - Hello OpenFL
+	Copyright (c) 2022 Bowler Hat LLC
+	PureMVC AS3 / Flash Demo - HelloFlash
+	By Cliff Hall <clifford.hall@puremvc.org>
+	Copyright(c) 2007-08, Some rights reserved.
+ */
+
+package org.puremvc.haxe.demos.openfl.helloopenfl.view;
+
+import openfl.events.Event;
+import org.puremvc.haxe.demos.openfl.helloopenfl.ApplicationFacade;
+import org.puremvc.haxe.demos.openfl.helloopenfl.model.SpriteDataProxy;
+import org.puremvc.haxe.demos.openfl.helloopenfl.view.components.HelloSprite;
+import org.puremvc.haxe.interfaces.IMediator;
+import org.puremvc.haxe.interfaces.INotification;
+import org.puremvc.haxe.patterns.mediator.Mediator;
+
+/**
+	A Mediator for interacting with the HelloSprite.
+**/
+class HelloSpriteMediator extends Mediator implements IMediator {
+	/**
+		Constructor. 
+	**/
+	public function new(viewComponent:HelloSprite) {
+		// pass the viewComponent to the superclass where
+		// it will be stored in the inherited viewComponent property
+		//
+		// *** Note that the name of the mediator is the same as the
+		// *** id of the HelloSprite it stewards. It does not use a
+		// *** fixed 'NAME' constant as most single-use mediators do
+		super(viewComponent.id, viewComponent);
+
+		// Retrieve reference to frequently consulted Proxies
+		spriteDataProxy = cast(facade.retrieveProxy(SpriteDataProxy.NAME), SpriteDataProxy);
+
+		// Listen for events from the view component
+		helloSprite.addEventListener(HelloSprite.SPRITE_DIVIDE, onSpriteDivide);
+	}
+
+	/**
+		List all notifications this Mediator is interested in.
+
+		Automatically called by the framework when the mediator
+		is registered with the view.
+
+		@return Array the list of Notification names
+	**/
+	override public function listNotificationInterests():Array<String> {
+		return [ApplicationFacade.SPRITE_SCALE, ApplicationFacade.SPRITE_DROP];
+	}
+
+	/**
+		Handle all notifications this Mediator is interested in.
+
+		Called by the framework when a notification is sent that
+		this mediator expressed an interest in when registered
+		(see `listNotificationInterests`).
+
+		@param INotification a notification 
+	**/
+	override public function handleNotification(note:INotification):Void {
+		switch (note.getName()) {
+			case ApplicationFacade.SPRITE_DROP:
+				helloSprite.dropSprite();
+
+			case ApplicationFacade.SPRITE_SCALE:
+				var delta = (note.getBody() : Int);
+				helloSprite.scaleSprite(delta);
+		}
+	}
+
+	/**
+		Sprite divide.
+
+		User is dragging the sprite, send a notification to create a new sprite
+		and pass the state the new sprite should inherit.
+	**/
+	private function onSpriteDivide(event:Event):Void {
+		helloSprite.color = spriteDataProxy.nextSpriteColor(helloSprite.color);
+		sendNotification(ApplicationFacade.STAGE_ADD_SPRITE, helloSprite.newSpriteState);
+	}
+
+	/**
+		Cast the viewComponent to its actual type.
+
+		This is a useful idiom for mediators. The
+		PureMVC Mediator class defines a viewComponent
+		property of type Object.
+
+		Here, we cast the generic viewComponent to 
+		its actual type in a protected mode. This 
+		retains encapsulation, while allowing the instance
+		(and subclassed instance) access to a 
+		strongly typed reference with a meaningful
+		name.
+
+		@return app the viewComponent cast to HelloSprite
+	**/
+	private var helloSprite(get, never):HelloSprite;
+
+	private function get_helloSprite():HelloSprite {
+		return cast(viewComponent, HelloSprite);
+	}
+
+	private var spriteDataProxy:SpriteDataProxy;
+}