added com.jfrog.bintray plugin for publishing

Author: Martin

build.gradle

@@ -19,14 +19,32 @@ plugins {
      *   Android>Lint>Correctness>Obsolete Gradle Dependency
      */
     id 'com.github.ben-manes.versions' version '0.14.0'
+    // for publishing
+    id "com.jfrog.bintray" version "1.7.3"
 }
 
+// https://docs.travis-ci.com/user/environment-variables/
+def isCi = System.getenv("TRAVIS") != null
+
 group 'com.tmtron.enums'
 version '1.0-SNAPSHOT'
+description 'Annotation processor that builds an enum mapper which causes a compile-time error when you forget an enum'
+ext {
+    bintrayDryRun = true
+}
 
 subprojects {
     apply plugin: 'java'
 
+    if (!isCi) {
+        // we don't need the bintray features for the ci build
+        apply from: rootProject.file('gradle/bintray.gradle')
+    }
+
+    /*
+     when I activate the licesne pluign, the bintray plugin creates an invalid pom file!
+     http://stackoverflow.com/questions/43820811/using-the-bintray-plugin-and-license-gradle-plugin-together
+
     apply plugin: "com.github.hierynomus.license"
     license {
         header rootProject.file('LICENSE_HEADER')
@@ -36,24 +54,7 @@ subprojects {
         }
         ext.year = Calendar.getInstance().get(Calendar.YEAR)
     }
-
-    /* create a jar for sources and java-docs
-     * http://stackoverflow.com/a/11475089/6287240
-     */
-    task sourcesJar(type: Jar, dependsOn: classes) {
-        classifier = 'sources'
-        from sourceSets.main.allSource
-    }
-
-    task javadocJar(type: Jar, dependsOn: javadoc) {
-        classifier = 'javadoc'
-        from javadoc.destinationDir
-    }
-
-    artifacts {
-        archives sourcesJar
-        archives javadocJar
-    }
+    */
 }
 
 repositories {

gradle/bintray.gradle

@@ -0,0 +1,114 @@
+apply plugin: 'maven'
+apply plugin: 'maven-publish'
+apply plugin: 'com.jfrog.bintray'
+
+def vcProvider = 'github'
+def vcProviderUser = 'tmtron'
+def vcProviderProject = 'enum-mapper'
+// e.g. https://github.com/tmtron/enum-mapper
+def vcProviderUrl = "https://${vcProvider}.com/${vcProviderUser}/${vcProviderProject}"
+def vcProviderScmUrl = "scm:git:${vcProviderUrl}.git"
+def bintrayPackage = "com.tmtron.${vcProviderProject}"
+
+bintray {
+    // defined in ~/.gradle/gradle.properties
+    user = "$bintray_user"
+    key = "$bintray_api_key"
+    publications = ['PublicationTmtron']
+    pkg {
+        repo = 'maven'
+        name = bintrayPackage
+        licenses = ['Apache-2.0']
+        vcsUrl = vcProviderScmUrl
+        version {
+            name = "$project.version"
+            gpg {
+                sign = true
+            }
+        }
+    }
+    // whether to run this as dry-run, without deploying
+    dryRun = bintrayDryRun
+}
+
+if (!bintrayDryRun) {
+    if ("$project.version".endsWith('-SNAPSHOT')) {
+        throw new GradleException("BinTray: uploading s snapshot version " +
+                ">$project.version< is not allowed!" +
+                "\nChange the version number or set ext.bintrayDryRun=true")
+    }
+}
+
+bintrayUpload.doLast {
+    if (bintrayDryRun) {
+        System.err.println "BinTray: DryRun is true!"
+    }
+}
+
+/* create a jar for sources and java-docs
+ * http://stackoverflow.com/a/11475089/6287240
+ */
+task sourcesJar(type: Jar, dependsOn: classes) {
+    from sourceSets.main.allSource
+    classifier = 'sources'
+}
+
+task javadocJar(type: Jar, dependsOn: javadoc) {
+    from javadoc.destinationDir
+    classifier = 'javadoc'
+}
+
+jar.dependsOn sourcesJar
+jar.dependsOn javadocJar
+
+artifacts {
+    archives sourcesJar
+    archives javadocJar
+}
+
+// Create the pom configuration:
+def pomConfig = {
+    licenses {
+        license {
+            name "The Apache Software License, Version 2.0"
+            url "http://www.apache.org/licenses/LICENSE-2.0.txt"
+            distribution "repo"
+        }
+    }
+    developers {
+        developer {
+            id "martin"
+            name "Martin"
+            email "martin@tmtron.com"
+        }
+    }
+    scm {
+        connection vcProviderScmUrl
+        developerConnection vcProviderScmUrl
+        url "${vcProviderUrl}/tree/master"
+    }
+}
+
+// Create the publication with the pom configuration:
+publishing {
+    publications {
+        PublicationTmtron(MavenPublication) {
+            from components.java
+
+            artifact sourcesJar
+            artifact javadocJar
+
+            groupId "$project.group"
+            artifactId "$project.name"
+            version "$project.version"
+
+            pom.withXml {
+                def root = asNode()
+                root.appendNode('description', project.description)
+                root.appendNode('name', "${project.group}:${project.name}")
+                root.appendNode('url', vcProviderUrl)
+                root.children().last() + pomConfig
+            }
+        }
+    }
+}