Move Gradle dependencyManagement configuration

The root project builds aggregated Javadoc.
Therefore, it needs access to the `platform` dependencies

* Move `dependencyManagement` configuration declaration into the `allprojects` section
* Refactor `dependencyManagement` configuration declaration according to the
idiomatic Groovy DSL for Gradle
* Add `cacheChangingModulesFor 0` to avoid caching for SNAPSHOTs
* Refactor `extendsFrom(dependencyManagement)` according to Groovy DSL for Gradle
* Extends `javadocClasspath` configuration in the root project from the `dependencyManagement`
to make Javadoc aggregation happy in regards to the required classpath

Author: artembilan

build.gradle

@@ -107,6 +107,30 @@ allprojects {
 		}
 //		maven { url 'https://repo.spring.io/libs-staging-local' }
 	}
+
+	configurations {
+		dependencyManagement {
+			canBeConsumed = false
+			canBeResolved = false
+		}
+
+		configureEach {
+			resolutionStrategy.cacheChangingModulesFor 0, 'minutes'
+		}
+	}
+
+	dependencies {
+		dependencyManagement(platform("com.fasterxml.jackson:jackson-bom:$jacksonBomVersion"))
+		dependencyManagement(platform("tools.jackson:jackson-bom:$jackson3Version"))
+		dependencyManagement(platform("org.junit:junit-bom:$junitJupiterVersion"))
+		dependencyManagement(platform("org.springframework:spring-framework-bom:$springVersion"))
+		dependencyManagement(platform("io.projectreactor:reactor-bom:$reactorVersion"))
+		dependencyManagement(platform("org.apache.logging.log4j:log4j-bom:$log4jVersion"))
+		dependencyManagement(platform("org.springframework.data:spring-data-bom:$springDataVersion"))
+		dependencyManagement(platform("io.micrometer:micrometer-bom:$micrometerVersion"))
+		dependencyManagement(platform("io.micrometer:micrometer-tracing-bom:$micrometerTracingVersion"))
+		dependencyManagement(platform("org.testcontainers:testcontainers-bom:$testcontainersVersion"))
+	}
 }
 
 ext {
@@ -159,29 +183,14 @@ configure(javaProjects) { subproject ->
 		}
 	}
 
-	configurations.create("dependencyManagement") {
-		canBeConsumed = false
-		canBeResolved = false
-
-		configurations["compileClasspath"].extendsFrom(it)
-		configurations["runtimeClasspath"].extendsFrom(it)
-		configurations["testCompileClasspath"].extendsFrom(it)
-		configurations["testRuntimeClasspath"].extendsFrom(it)
+	configurations {
+		[compileClasspath, runtimeClasspath, testCompileClasspath, testRuntimeClasspath].each {
+			it.extendsFrom(dependencyManagement)
+		}
 	}
 
 	// dependencies that are common across all java projects
 	dependencies {
-		dependencyManagement(platform("com.fasterxml.jackson:jackson-bom:$jacksonBomVersion"))
-		dependencyManagement(platform("tools.jackson:jackson-bom:$jackson3Version"))
-		dependencyManagement(platform("org.junit:junit-bom:$junitJupiterVersion"))
-		dependencyManagement(platform("org.springframework:spring-framework-bom:$springVersion"))
-		dependencyManagement(platform("io.projectreactor:reactor-bom:$reactorVersion"))
-		dependencyManagement(platform("org.apache.logging.log4j:log4j-bom:$log4jVersion"))
-		dependencyManagement(platform("org.springframework.data:spring-data-bom:$springDataVersion"))
-		dependencyManagement(platform("io.micrometer:micrometer-bom:$micrometerVersion"))
-		dependencyManagement(platform("io.micrometer:micrometer-tracing-bom:$micrometerTracingVersion"))
-		dependencyManagement(platform("org.testcontainers:testcontainers-bom:$testcontainersVersion"))
-
 		testImplementation 'org.apache.logging.log4j:log4j-core'
 		testImplementation "org.hamcrest:hamcrest-core:$hamcrestVersion"
 		testImplementation("org.mockito:mockito-core:$mockitoVersion") {
@@ -526,6 +535,8 @@ dependencies {
 	}
 }
 
+configurations.javadocClasspath.extendsFrom(configurations.dependencyManagement)
+
 javadoc {
 	title = "${rootProject.description} ${version} API"
 	options {