Add support for creating PCIe root ports in QEMU

Author: nesteroff

lib/runners/qemu.nix

@@ -54,7 +54,7 @@ let
     else "threads";
 
   inherit (microvmConfig) hostName vcpu mem balloon initialBalloonMem deflateOnOOM hotplugMem hotpluggedMem user interfaces shares socket forwardPorts devices vsock graphics storeOnDisk kernel initrdPath storeDisk credentialFiles;
-  inherit (microvmConfig.qemu) machine extraArgs serialConsole;
+  inherit (microvmConfig.qemu) machine extraArgs serialConsole pcieRootPorts;
 
 
   volumes = withDriveLetters microvmConfig;
@@ -197,11 +197,24 @@ lib.warnIf (mem == 2048) ''
 
       "-chardev" "stdio,id=stdio,signal=off"
       "-device" "virtio-rng-${devType}"
-    ])
+    ] ++
+      # Create PCIe root ports before vfio-pci devices that might require them
+      builtins.concatMap ({ id, bus, chassis, slot, addr, ... }:
+        [ "-device" "pcie-root-port,id=${id}${
+            lib.optionalString (bus != null) ",bus=${bus}" +
+            lib.optionalString (chassis != null) ",chassis=${toString chassis}" +
+            lib.optionalString (slot != null) ",slot=${slot}" +
+            lib.optionalString (addr != null) ",addr=${addr}"
+          }"
+        ]
+      ) pcieRootPorts
+    )
     + " " + # Move vfio-pci outside of escapeShellArgs
     lib.concatStringsSep " " (lib.concatMap ({ bus, path, qemu,... }: {
       pci = [
         "-device" "vfio-pci,host=${path},multifunction=on${
+          lib.optionalString (qemu.id != null) ",id=${qemu.id}" +
+          lib.optionalString (qemu.bus != null) ",bus=${qemu.bus}" +
           # Allow to pass additional arguments to pci device
           lib.optionalString (qemu.deviceExtraArgs != null) ",${qemu.deviceExtraArgs}"
         }"

nixos-modules/microvm/options.nix

@@ -421,12 +421,28 @@ in
               Identification of the device on its bus
             '';
           };
-          qemu.deviceExtraArgs = mkOption {
-            type =  with types; nullOr str;
-            default = null;
-            description = ''
-              Device additional arguments (optional)
-            '';
+          qemu = {
+            id = mkOption {
+              type = nullOr str;
+              default = null;
+              description = ''
+                QEMU device identifier (optional)
+              '';
+            };
+            bus = mkOption {
+              type = nullOr str;
+              default = null;
+              description = ''
+                QEMU bus to which this device is attached (optional)
+              '';
+            };
+            deviceExtraArgs = mkOption {
+              type =  nullOr str;
+              default = null;
+              description = ''
+                Device additional arguments (optional)
+              '';
+            };
           };
         };
       });
@@ -559,6 +575,64 @@ in
       '';
     };
 
+    qemu.pcieRootPorts = mkOption {
+      description = ''
+        A list of PCIe root ports that can be used for hot-plugging PCIe devices.
+        This is particularly useful on the Q35 machine type, which does not support
+        hot-plugging on the base PCIe root bus (pcie.0). Creating root ports allows
+        attaching and detaching PCIe devices at runtime and can also be useful for
+        devices that require their own dedicated PCIe slot with a fixed address, etc.
+        For additional details see the QEMU PCI Express Guidelines:
+        <https://gitlab.com/qemu-project/qemu/-/blob/master/docs/pcie.txt>
+      '';
+      default = [];
+      example = literalExpression /* nix */ ''
+        [ {
+          bus = "pcie.0";
+          id = "pci_port_0";
+          chassis = 0;
+        } ]
+      '';
+      type = with types; listOf (submodule {
+        options = {
+          id = mkOption {
+            type = str;
+            description = ''
+              A unique identifier for this PCIe root port.
+            '';
+          };
+          bus = mkOption {
+            type = nullOr str;
+            default = null;
+            description = ''
+              The PCIe bus on which the root port will be created.
+            '';
+          };
+          chassis = mkOption {
+            type = nullOr int;
+            default = null;
+            description = ''
+              The chassis number associated with this PCIe root port.
+            '';
+          };
+          slot = mkOption {
+            type = nullOr str;
+            default = null;
+            description = ''
+              PCIe slot number.
+            '';
+          };
+          addr = mkOption {
+            type = nullOr str;
+            default = null;
+            description = ''
+              PCIe address on the parent bus.
+            '';
+          };
+        };
+      });
+    };
+
     cloud-hypervisor.platformOEMStrings = mkOption {
       type = with types; listOf str;
       default = [];