continue in loop

[uvtc]

How can I "continue" in a loop? For example, suppose I'm looping on asking the user for input. If the input is bad, I want to discontinue the loop and start it over again. break breaks me out of the loop permanently -- I only want out for the current iteration.

Here's an example:

#!/usr/bin/env janet

(defn get-user-input
  [s]
  (prin s)
  (flush)
  (string/trim (getline)))

(defn main
  [args]
  (while true
    (def num (scan-number
               (get-user-input "Enter a num: ")))

    (when (< 100 num)
      (print "Too high. Keep it under 100.")
      (break)) # <-- how can I instead `continue` here?

    (print "Ok, " num)))

It was suggested to me to try loop. I came up with:

(defn main
  [args]
  (loop [num :iterate (scan-number
                        (get-user-input "Num?: "))
         :when (> 100 num)]
    (print (string "Ok, you supplied " num "."))))

but then how do I also print out the message asking the user to choose a number below 100?

[sogaiu]

@uvtc How about using prompt with return (I think this was another of @yumaikas' ideas) in the following manner:

(defn main
  [args]
  (while true
    (prompt :top
    
      (def num (scan-number
                 (get-user-input "Enter a num: ")))

      (when (< 100 num)
        (print "Too high. Keep it under 100.")
        (return :top))

      (print "Ok, " num))))

FWIW, I got the following sort of output in one trial:

$ janet continue.janet 
Enter a num: 2
Ok, 2
Enter a num: 101
Too high. Keep it under 100.
Enter a num: 

[yumaikas]

So, after, while admittedly very tired, trying to play with loop to get it to try to do something like this, I think prompt/return is the way to go. loop has a lot of filtering options, and :before and :after can be used to some good effect in other situations, I don't think loop is quite the right fit here.

[uvtc]

Thanks, @sogaiu and @yumaikas .

In the chat, @bakpakin noted that label is basically like prompt, but lexically-scoped.

I see that label works here as well, if you change :top to 'top:

#!/usr/bin/env janet

(import ../janet-lib/john/io)

(defn main
  [& args]
  (while true
    (label 'top
      (def num (scan-number (io/get-user-input "Num? ")))
            
      (when (< 100 num)
        (print "Too high. Keep it under 100.")
        (return 'top))

      (print "ok. you entered " num))))

As you (@sogaiu) pointed out in the chat, I see that label is implemented in terms of prompt ... and @bakpakin added more info besides. I'll need to experiment more here to see how they're different. Maybe the topic of another discussion.