partition-by ?

[uvtc]

I see that Janet already has partition, but I wanted to be able to step through an array and create sub-arrays of it whenever the result of some (f e) (calling f on an element e of the array) changed.

I initially thought f should be a function of two args --- the curr and next array elems --- but it looks simpler if I just check to see if (f e) changes.

Here's what I came up with:

(defn partition-by
  [f a]
  (def res @[ @[(first a)] ])
  (loop [e :in (drop 1 a)]
    (if (= (f e)
           (f (last (last res))))
      (array/push (last res) e)
      (array/push res @[e])))
  res)

(def a [3 7 9 6 2 1 7 8 6 4 5])

(pp (partition-by even? a))
# @[@[3 7 9] @[6 2] @[1 7] @[8 6 4] @[5]]

How does that look? Suggestions for improvement appreciated.

[pyrmont]

The above doesn't handle the case where a is [] and it creates an intermediate array at the start of the loop that could be a bit costly (depending on the size of the input).

Here's my suggestion:

(defn partition-by
  [f coll]
  (def res @[])
  (var prev nil)
  (loop [e :in coll
           :let [curr (f e)]]
    (cond
      (zero? (length res))
      (array/push res @[e])

      (= curr prev)
      (array/push (last res) e)

      (array/push res @[e]))
    (set prev curr))
  res)

[uvtc]

Thanks, @pyrmont . Ah, yes, I see my (drop 1 a) creates an intermediate array. Is my initial code creating any others?

Also, what's your purpose for putting in (or (one? i)? It fails if the input array starts with, say, [3 4.

[pyrmont]

Yeah, sorry, I had a brain explosion. I thought the call to drop occurred inside the loop for some reason. Made some adjustments (now much closer to your original) that I think fix the problems :)

[uvtc]

Cool, thanks, @pyrmont . Also, I'd forgotten about :let in loop.

[pyrmont]

Just noting that group-by and partition-by are now in core in master via c909762.