feat: add terraform resources to setup ecs cluster

Author: Premdeep Saini

.gitignore

@@ -0,0 +1,4 @@
+.DS_Store
+.idea
+.envrc
+.terraform/

README.md

@@ -0,0 +1,8 @@
+### ECS Terraform Module
+
+This module provides resources for the setup of ECS cluster. This includes:
+
+- ECS cluster
+- Capacity Providers
+- Auto scaling groups
+- Launch Configurations

auto_scaling_groups.tf

@@ -0,0 +1,43 @@
+resource "aws_launch_configuration" "ecs_launch_config" {
+  for_each             = { for launch_config_name, launch_config in var.launch_configs : launch_config.name => launch_config }
+  name                 = "${var.environment}_ecs_${each.value.name}"
+  image_id             = each.value.image_id
+  instance_type        = each.value.instance_type
+  user_data_base64     = each.value.user_data_base64
+  iam_instance_profile = each.value.iam_instance_profile_name
+  security_groups      = each.value.security_group_ids
+  lifecycle {
+    create_before_destroy = true
+  }
+}
+
+resource "aws_autoscaling_group" "ecs_cluster_asg" {
+  for_each                  = { for asg_name, asg in var.asg : asg.name => asg }
+  name                      = "${var.environment}_ecs_${each.value.name}"
+  vpc_zone_identifier       = each.value.vpc_zone_identifier
+  health_check_type         = each.value.health_check_type
+  health_check_grace_period = each.value.health_check_grace_period
+  launch_configuration      = aws_launch_configuration.ecs_launch_config[each.key].name
+  max_size                  = each.value.max_size
+  min_size                  = each.value.max_size
+  protect_from_scale_in     = each.value.protect_from_scale_in
+  tag {
+    key                 = "Name"
+    propagate_at_launch = true
+    value               = "${var.environment}_ecs_${each.value.name}"
+  }
+  tag {
+    key                 = "ManagedBy"
+    propagate_at_launch = false
+    value               = local.managed_by
+  }
+  tag {
+    key                 = "Environment"
+    propagate_at_launch = true
+    value               = var.environment
+  }
+  lifecycle {
+    create_before_destroy = true
+  }
+  depends_on = [aws_launch_configuration.ecs_launch_config]
+}

main.tf

@@ -0,0 +1,35 @@
+locals {
+  managed_by = "Terraform"
+}
+
+resource "aws_ecs_cluster" "ecs_cluster" {
+  name = var.cluster_name
+  tags = {
+    "Name"        = var.cluster_name
+    "ManagedBy"   = local.managed_by
+    "Environment" = var.environment
+  }
+}
+
+resource "aws_ecs_capacity_provider" "capacity_providers" {
+  for_each = { for name, capacity_provider in var.capacity_providers : capacity_provider.name => capacity_provider }
+  name     = "${var.environment}_ecs_${each.value.name}"
+  auto_scaling_group_provider {
+    auto_scaling_group_arn = aws_autoscaling_group.ecs_cluster_asg[each.key].arn
+    managed_scaling {
+      target_capacity = each.value.target_capacity
+      status          = each.value.managed_scaling_status
+    }
+    managed_termination_protection = each.value.managed_termination_protection
+  }
+  tags = {
+    "ManagedBy" = local.managed_by
+  }
+  depends_on = [aws_autoscaling_group.ecs_cluster_asg]
+}
+
+resource "aws_ecs_cluster_capacity_providers" "ecs_cluster_capacity_provider" {
+  cluster_name       = aws_ecs_cluster.ecs_cluster.name
+  capacity_providers = [for cp in aws_ecs_capacity_provider.capacity_providers : cp.name]
+  depends_on         = [aws_ecs_capacity_provider.capacity_providers]
+}

outputs.tf

@@ -0,0 +1,48 @@
+variable "environment" {
+  type        = string
+  description = "Environment. Example: staging, production."
+}
+variable "cluster_name" {
+  type        = string
+  description = "Name of ECS cluster."
+}
+variable "vpc_id" {
+  type        = string
+  description = "AWS VPC identifier for ECS cluster"
+}
+variable "vpc_cidr_block" {
+  type        = string
+  description = "CIDR block for VPC."
+}
+variable "capacity_providers" {
+  type = list(object({
+    name                           = string
+    target_capacity                = number
+    managed_scaling_status         = string
+    managed_termination_protection = string
+  }))
+  description = "Capacity provider configuration."
+}
+variable "asg" {
+  type = list(object({
+    name                      = string
+    vpc_zone_identifier       = list(string)
+    health_check_type         = string
+    health_check_grace_period = number
+    max_size                  = number
+    min_size                  = number
+    protect_from_scale_in     = bool
+  }))
+  description = "Autoscaling group configuration."
+}
+variable "launch_configs" {
+  type = list(object({
+    name                      = string
+    image_id                  = string
+    instance_type             = string
+    user_data_base64          = string
+    iam_instance_profile_name = string
+    security_group_ids        = list(string)
+  }))
+  description = "Launch configuration for EC2 instances."
+}

variables.tf

@@ -0,0 +1,13 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "~> 4.16"
+    }
+    cloudinit = {
+      source  = "hashicorp/cloudinit"
+      version = ">=2.2.0"
+    }
+  }
+  required_version = ">= 1.2.0"
+}