Dedup AppVeyor builds

Author: wilzbach

README.md

@@ -16,6 +16,7 @@ Features
 - [Send contributing advice message](#hello-contributor)
 - [Auto-label PRs](#auto-labelling)
 - [Using the Dlang-Bot for your project](#dlang-bot-for-your-project)
+- [Canceling stale AppVeyor builds](#canceling-stale)
 - [Missing a feature?](#missing-a-feature)
 
 <a name="automated-references" />
@@ -207,6 +208,15 @@ For example, `dlang/phobos` is configured as follows:
 
 ![image](https://user-images.githubusercontent.com/4370550/27859920-b418a38e-617a-11e7-9ff2-c1fd9f6fdd20.png)
 
+<a name="#canceling-stale" />
+
+Canceling stale AppVeyor builds
+-------------------------------
+
+To avoid wasteful resource consumption with Travis CI,
+the Dlang-Bot will automatically cancel the previous, possibly running build of
+a PR on a new commit event (push or synchronization by a user).
+
 <a name="missing-a-feature" />
 
 Missing a feature?

source/dlangbot/app.d

@@ -1,8 +1,13 @@
 module dlangbot.app;
 
-import dlangbot.bugzilla, dlangbot.cron, dlangbot.github, dlangbot.trello,
-       dlangbot.utils;
-
+import dlangbot.appveyor;
+import dlangbot.bugzilla;
+import dlangbot.cron;
+import dlangbot.github;
+import dlangbot.trello;
+import dlangbot.utils;
+
+public import dlangbot.appveyor : appveyorAPIURL, appveyorAuth;
 public import dlangbot.bugzilla : bugzillaURL;
 public import dlangbot.github_api   : githubAPIURL, githubAuth, hookSecret;
 public import dlangbot.trello   : trelloAPIURL, trelloAuth, trelloSecret;
@@ -21,6 +26,7 @@ import vibe.stream.operations : readAllUTF8;
 
 bool runAsync = true;
 bool runTrello = true;
+bool runAppVeyor = true;
 
 Duration timeBetweenFullPRChecks = 1.minutes; // this should never be larger 30 mins on heroku
 Throttler!(typeof(&searchForAutoMergePrs)) prThrottler;
@@ -230,6 +236,24 @@ void handlePR(string action, PullRequest* _pr)
         logDebug("[github/handlePR](%s): updating trello card", _pr.pid);
         updateTrelloCard(action, pr.htmlURL, refs, descs);
     }
+
+
+    // wait until builds for the current push are created
+    if (pr.repoSlug == "dlang/dmd" && runAppVeyor)
+    {
+        // AppVeyor doesn't support organizations natively
+        import std.array : replace;
+        auto repoSlug = pr.repoSlug.replace("dlang/dmd", "greenify/dmd");
+        setBotTimer(30.seconds, { dedupAppVeyorBuilds(action, repoSlug, pr.number); });
+    }
+}
+
+void setBotTimer(C)(Duration dur, C callback)
+{
+    if (runAsync)
+        setTimer(dur, callback);
+    else
+        callback();
 }
 
 //==============================================================================
@@ -254,6 +278,7 @@ else void main(string[] args)
     trelloSecret = environment["TRELLO_SECRET"];
     trelloAuth = "key="~environment["TRELLO_KEY"]~"&token="~environment["TRELLO_TOKEN"];
     hookSecret = environment["GH_HOOK_SECRET"];
+    appveyorAuth = "Bearer " ~ environment["APPVEYOR_TOKEN"];
 
     // workaround for stupid openssl.conf on Heroku
     if (environment.get("DYNO") !is null)

source/dlangbot/appveyor.d

@@ -0,0 +1,67 @@
+module dlangbot.appveyor;
+
+string appveyorAPIURL = "https://ci.appveyor.com/api";
+string appveyorAuth;
+
+import vibe.core.log;
+
+//==============================================================================
+// Dedup AppVeyor builds
+//==============================================================================
+
+// https://www.appveyor.com/docs/api/projects-builds/#cancel-build
+void cancelBuild(string repoSlug, size_t buildId)
+{
+    import std.format : format;
+    import vibe.http.client : requestHTTP;
+    import vibe.http.common : HTTPMethod;
+    import vibe.stream.operations : readAllUTF8;
+
+    auto url = "%s/builds/%s/%s/cancel".format(appveyorAPIURL, repoSlug, buildId);
+    requestHTTP(url, (scope req) {
+        req.headers["Authorization"] = appveyorAuth;
+        req.method = HTTPMethod.DELETE;
+    }, (scope res) {
+        if (res.statusCode / 100 == 2)
+            logInfo("[appveyor/%s]: Canceled Build %s\n", repoSlug, buildId);
+        else
+            logWarn("[appveyor/%s]: POST %s failed;  %s %s.\n%s", repoSlug, url, res.statusPhrase,
+                res.statusCode, res.bodyReader.readAllUTF8);
+    });
+}
+
+// https://www.appveyor.com/docs/api/projects-builds/#get-project-history
+void dedupAppVeyorBuilds(string action, string repoSlug, uint pullRequestNumber)
+{
+    import std.algorithm.iteration : filter;
+    import std.conv : to;
+    import std.format : format;
+    import std.range : drop;
+    import vibe.data.json : Json;
+    import vibe.http.client : requestHTTP;
+
+    if (action != "synchronize" && action != "merged")
+        return;
+
+    static bool activeState(string state)
+    {
+        import std.algorithm.comparison : among;
+        return state.among("created", "queued", "started") > 0;
+    }
+    // GET /api/projects/{accountName}/{projectSlug}/history?recordsNumber={records-per-page}[&startBuildId={buildId}&branch={branch}]
+
+    auto url = "%s/projects/%s/history?recordsNumber=100".format(appveyorAPIURL, repoSlug);
+    auto activeBuildsForPR = requestHTTP(url, (scope req) {
+            req.headers["Authorization"] = appveyorAuth;
+        })
+        .readJson["builds"][]
+        .filter!(b => "pullRequestId" in b && !b["pullRequestId"].type != Json.undefined)
+        .filter!(b => activeState(b["status"].get!string))
+        .filter!(b => b["pullRequestId"].get!string.to!uint == pullRequestNumber);
+
+    // Keep only the most recent build for this PR.  Kill all builds
+    // when it got merged as it'll be retested after the merge anyhow.
+    foreach (b; activeBuildsForPR.drop(action == "merged" ? 0 : 1))
+        cancelBuild(repoSlug, b["buildId"].get!size_t);
+}
+

test/appveyor.d

@@ -0,0 +1,38 @@
+import utils;
+
+unittest
+{
+    setAPIExpectations(
+        "/github/repos/dlang/dmd/pulls/6359/commits", (ref Json j) {
+            j = Json.emptyArray;
+        },
+        "/github/repos/dlang/dmd/issues/6359/comments",
+        "/github/orgs/dlang/public_members?per_page=100",
+        "/github/repos/dlang/dmd/issues/6359/comments", // dlang-bot post
+        "/github/repos/dlang/dmd/issues/6359/labels",
+        "/appveyor/projects/greenify/dmd/history?recordsNumber=100", (ref Json j) {
+            j["builds"][0]["status"] = "queued";
+            j["builds"][1]["status"] = "queued";
+            j["builds"][2]["status"] = "cancelled";
+            j["builds"][0]["pullRequestId"] = "6359";
+            j["builds"][1]["pullRequestId"] = "6359";
+            j["builds"][2]["pullRequestId"] = "6359";
+            j["builds"] = j["builds"][0..2];
+        },
+        "/appveyor/builds/greenify/dmd/13074433/cancel",
+        (scope HTTPServerRequest req, scope HTTPServerResponse res) {
+            assert(req.method == HTTPMethod.DELETE);
+            res.statusCode = 204;
+            res.writeVoidBody;
+        },
+    );
+
+    runAppVeyor = true;
+    scope(exit) runAppVeyor = false;
+    postGitHubHook("dlang_phobos_synchronize_4921.json", "pull_request", (ref Json j, scope req){
+        j["pull_request"]["number"] = 6359;
+        j["pull_request"]["base"]["repo"]["name"] = "dmd";
+        j["pull_request"]["base"]["repo"]["full_name"] = "dlang/dmd";
+        j["pull_request"]["base"]["repo"]["owner"]["login"] = "dlang";
+    });
+}

test/utils.d

@@ -40,6 +40,7 @@ shared static this()
     githubAuth = "GH_DUMMY_AUTH_TOKEN";
     hookSecret = "GH_DUMMY_HOOK_SECRET";
     trelloAuth = "key=01234&token=abcde";
+    appveyorAuth = "key=01234&token=abcde";
 
     // start our hook server
     auto settings = new HTTPServerSettings;
@@ -56,6 +57,7 @@ shared static this()
     setLogLevel(LogLevel.info);
 
     runAsync = false;
+    runAppVeyor = false;
 }
 
 void startFakeAPIServer()
@@ -75,6 +77,7 @@ void startFakeAPIServer()
     githubAPIURL = fakeAPIServerURL ~ "/github";
     trelloAPIURL = fakeAPIServerURL ~ "/trello";
     bugzillaURL = fakeAPIServerURL ~ "/bugzilla";
+    appveyorAPIURL = fakeAPIServerURL ~ "/appveyor";
 }
 
 // serves saved GitHub API payloads
@@ -124,7 +127,7 @@ auto payloadServer(scope HTTPServerRequest req, scope HTTPServerResponse res)
     {
         logInfo("reading payload: %s", filePath);
         auto payload = filePath.readText;
-        if (req.requestURL.startsWith("/github", "/trello"))
+        if (req.requestURL.startsWith("/github", "/trello", "/appveyor"))
         {
             auto payloadJson = payload.parseJsonString;
             replaceAPIReferences("https://api.github.com", githubAPIURL, payloadJson);