error uniform.type == GL_SAMPLER_2D or GL_SAMPLER_CUBE after shader compile

[10100010010001001010]

my fragment shader:

#version 300 es
precision mediump float;

layout(std140) uniform fs_ub {
    highp vec2 u_lightPos;
    highp float u_lightRad; 
    highp float u_darkness;     
} _15;

in vec4 v_position;
out vec4 FragColor;

void main()
{
    vec2 screenPos = v_position.xy * 0.5 + 0.5;

    float dist = distance(screenPos, _15.u_lightPos);

    float darknessFactor = smoothstep(_15.u_lightRad, _15.u_lightRad * 1.7, dist);

    float alpha = darknessFactor * _15.u_darkness;

    FragColor = vec4(0.0, 0.0, 0.0, alpha);
}

i want realise a simple darkness effect, but I get an error from title of topic. This error from string 392 of "ProgramGL.cpp" file, and i see a hint "must be sampler: sampler2D or samplerCube". But i dont use a texture, just vertices, like the shader from the tests called "quadColor_fs", the structure of which i was guided by.
Please help

[rh101]

You seem to have deleted lines from {axmol}/core/renderer/shaders/quadColor.frag that are actually required. Also, the quadColor_fs is the output shader, which you shouldn't be copying. Look at the original source at {axmol}/core/renderer/shaders/quadColor.frag etc..

Try something like this:

#version 310 es
precision mediump float;

layout(location = COLOR0) in vec4 v_color;
layout(location = TEXCOORD0) in vec2 v_texCoord;
layout(location = SV_Target0) out vec4 FragColor;

layout(binding = 0) uniform sampler2D u_tex0;

layout(std140) uniform fs_ub {
    highp vec2 u_lightPos;
    highp float u_lightRad; 
    highp float u_darkness;  
};

void main()
{
    vec2 screenPos = v_texCoord.xy * 0.5 + 0.5;

    float dist = distance(screenPos, u_lightPos);

    float darknessFactor = smoothstep(u_lightRad, u_lightRad * 1.7, dist);

    float alpha = darknessFactor * u_darkness;

    FragColor = vec4(0.0, 0.0, 0.0, alpha);
}

[10100010010001001010]

I tried this option, I still get a compilation error, I thought to look in the console, it says this:

[halx99]

as @rh101 said, don't load it directly, instead, read the shader workflow of axmol2: #1279

[rh101]

@10100010010001001010 The shader files must be located in {yourproject}/Source/shaders/, and not in Content/shaders/. When you build the application, the shaders files will be processed, and the correct files for the target will be generated.

In your case, with files named "vertex_shader.vsh" and "fragment_shader.fsh", two new files will be generated, named "vertex_shader_vs" and "fragment_shader_fs". In your code, you need to load these generated files, and not your original shaders. To reference them, you need to use the following:

custom/vertex_shader_vs
and
custom/fragment_shader_fs

Custom shaders included in projects are always prefixed with custom/.

[rh101]

Here are the fixed shaders based on your project and the original fragment shader you posted, where I accidentally removed v_position:

vertext_shader.vsh:

#version 310 es

layout(std140) uniform vs_ub {
    mat4 u_MVPMatrix;
};

layout(location = POSITION) in vec4 a_position;
layout(location = 0) out vec4 v_position;

void main()
{
    gl_Position = u_MVPMatrix * a_position;
    v_position = a_position;
}

and fragment_shader.fsh (with v_position re-added):

#version 310 es
precision mediump float;

layout(location = COLOR0) in vec4 v_color;
layout(location = POSITION) in vec4 v_position;
layout(location = SV_Target0) out vec4 FragColor;

layout(binding = 0) uniform sampler2D u_tex0;

layout(std140) uniform fs_ub {
    highp vec2 u_lightPos;
    highp float u_lightRad; 
    highp float u_darkness;  
};

void main()
{
    vec2 screenPos = v_position.xy * 0.5 + 0.5;

    float dist = distance(screenPos, u_lightPos);

    float darknessFactor = smoothstep(u_lightRad, u_lightRad * 1.7, dist);

    float alpha = darknessFactor * u_darkness;

    FragColor = vec4(0.0, 0.0, 0.0, alpha);
}

[10100010010001001010]

Thank you very much for the detailed explanation

[rh101]

I grabbed the info from #1279 and added it to the wiki here, since these shader questions seem to be coming up more often.