Decouple individual process-compose module

Also add a 'outputs.package' option.

Author: srid

nix/flake-module.nix

@@ -23,68 +23,15 @@ in
           process-compose-flake: creates [process-compose](https://github.com/F1bonacc1/process-compose)
           executables from process-compose configurations written as Nix attribute sets.
         '';
-        type = types.attrsOf (submoduleWithPkgs ({ config, ... }: {
+        type = types.attrsOf (submoduleWithPkgs {
           imports = [
-            ./settings.nix
+            ./process-compose
           ];
-          options = {
-            package = mkOption {
-              type = types.package;
-              default = pkgs.process-compose;
-              defaultText = lib.literalExpression "pkgs.process-compose";
-              description = ''
-                The process-compose package to bundle up in the command package and flake app.
-              '';
-            };
-            port = mkOption {
-              type = types.nullOr types.int;
-              default = null;
-              description = ''
-                Port to serve process-compose's Swagger API on.
-              '';
-            };
-            tui = mkOption {
-              type = types.nullOr types.bool;
-              default = null;
-              description = "Enable or disable the TUI for the application.";
-            };
-            extraCliArgs =
-              let
-                cliArgsAttr = {
-                  port = "-p ${toString config.port}";
-                  tui = "-t=${lib.boolToString config.tui}";
-                };
-                getCliArgs =
-                  lib.mapAttrsToList
-                    (opt: arg: lib.optionalString (config.${opt} != null) arg)
-                    cliArgsAttr;
-              in
-              mkOption {
-                type = types.str;
-                default = lib.concatStringsSep " " getCliArgs;
-                internal = true;
-                readOnly = true;
-                description = ''
-                  Extra command-line arguments to pass to process-compose.
-                '';
-              };
-          };
-        }));
+        });
       };
 
       config.packages = lib.mapAttrs
-        (name: cfg:
-          pkgs.writeShellApplication {
-            inherit name;
-            runtimeInputs = [ cfg.package ];
-            text = ''
-              process-compose up \
-                -f ${cfg.settingsYaml} \
-                ${cfg.extraCliArgs} \
-                "$@"
-            '';
-          }
-        )
+        (name: cfg: cfg.outputs.package)
         config.process-compose;
     });
 }

nix/process-compose/default.nix

@@ -0,0 +1,72 @@
+{ name, config, pkgs, lib, ... }: 
+
+let 
+  inherit (lib) types mkOption literalExpression;
+in 
+{
+  imports = [
+    ./settings.nix
+  ];
+
+  options = {
+    package = mkOption {
+      type = types.package;
+      default = pkgs.process-compose;
+      defaultText = lib.literalExpression "pkgs.process-compose";
+      description = ''
+        The process-compose package to bundle up in the command package and flake app.
+      '';
+    };
+    port = mkOption {
+      type = types.nullOr types.int;
+      default = null;
+      description = ''
+        Port to serve process-compose's Swagger API on.
+      '';
+    };
+    tui = mkOption {
+      type = types.nullOr types.bool;
+      default = null;
+      description = "Enable or disable the TUI for the application.";
+    };
+    extraCliArgs =
+      let
+        cliArgsAttr = {
+          port = "-p ${toString config.port}";
+          tui = "-t=${lib.boolToString config.tui}";
+        };
+        getCliArgs =
+          lib.mapAttrsToList
+            (opt: arg: lib.optionalString (config.${opt} != null) arg)
+            cliArgsAttr;
+      in
+      mkOption {
+        type = types.str;
+        default = lib.concatStringsSep " " getCliArgs;
+        internal = true;
+        readOnly = true;
+        description = ''
+          Extra command-line arguments to pass to process-compose.
+        '';
+      };
+    outputs.package = mkOption {
+      type = types.package;
+      description = ''
+        The final package that will run 'process-compose up' for this configuration.
+      '';
+    };
+  };
+
+  config.outputs.package =
+    pkgs.writeShellApplication {
+      inherit name;
+      runtimeInputs = [ config.package ];
+      text = ''
+        process-compose up \
+          -f ${config.settingsYaml} \
+          ${config.extraCliArgs} \
+          "$@"
+      '';
+    };
+}
+

nix/settings.nix nix/process-compose/settings.nixnix/settings.nix renamed to nix/process-compose/settings.nix

@@ -1,7 +1,8 @@
 { name, config, pkgs, lib, ... }: 
 let 
   inherit (lib) types mkOption literalExpression;
-in {
+in 
+{
   options = {
     settings = mkOption {
       type = (pkgs.formats.yaml { }).type;