Improve formatting of the crash reports

Author: AndrewDryga

lib/logger_json/formatters/elastic.ex

@@ -219,12 +219,31 @@ defmodule LoggerJSON.Formatters.Elastic do
     |> maybe_put(:"error.code", get_exception_code(exception))
   end
 
-  def format_crash_reason(message, {error, reason}, _meta) do
+  def format_crash_reason(message, {{{%type{} = exception, _}, _}, stacktrace}, _meta) do
+    formatted_stacktrace =
+      [
+        Exception.format_banner(:error, exception, stacktrace),
+        Exception.format_stacktrace(stacktrace)
+      ]
+      |> Enum.join("\n")
+
+    format_error_fields(message, Exception.message(exception), formatted_stacktrace, type)
+    |> maybe_put(:"error.id", get_exception_id(exception))
+    |> maybe_put(:"error.code", get_exception_code(exception))
+  end
+
+  def format_crash_reason(message, {error, reason}, _meta) when is_atom(error) or is_binary(error) do
     stacktrace = "** (#{error}) #{inspect(reason)}"
     error_message = "#{error}: #{inspect(reason)}"
     format_error_fields(message, error_message, stacktrace, error)
   end
 
+  def format_crash_reason(message, {error, reason}, _meta) do
+    stacktrace = "** (#{inspect(error)}) #{inspect(reason)}"
+    error_message = "#{inspect(error)}: #{inspect(reason)}"
+    format_error_fields(message, error_message, stacktrace, "error")
+  end
+
   defp get_exception_id(%{id: id}), do: id
   defp get_exception_id(_), do: nil
 

lib/logger_json/formatters/google_cloud.ex

@@ -188,6 +188,17 @@ defmodule LoggerJSON.Formatters.GoogleCloud do
     format_reported_error_event(message, ruby_stacktrace, service_context, meta)
   end
 
+  def format_crash_reason(message, {{{%{} = exception, _}, _}, stacktrace}, service_context, meta) do
+    ruby_stacktrace =
+      [
+        Exception.format_banner(:error, exception, stacktrace),
+        format_stacktrace(stacktrace)
+      ]
+      |> Enum.join("\n")
+
+    format_reported_error_event(message, ruby_stacktrace, service_context, meta)
+  end
+
   def format_crash_reason(binary, {error, reason}, service_context, meta) when is_atom(error) or is_binary(error) do
     stacktrace = "** (#{error}) #{inspect(reason)}"
     format_reported_error_event(binary, stacktrace, service_context, meta)

test/logger_json/formatters/elastic_test.exs

@@ -446,6 +446,49 @@ defmodule LoggerJSON.Formatters.ElasticTest do
     assert String.starts_with?(stacktrace, "** (RuntimeError) oops")
   end
 
+  test "logs Task/GenServer termination" do
+    test_pid = self()
+
+    logs =
+      capture_log(fn ->
+        {:ok, _} = Supervisor.start_link([{CrashingGenServer, :ok}], strategy: :one_for_one)
+
+        {:ok, _} =
+          Task.start(fn ->
+            try do
+              GenServer.call(CrashingGenServer, :boom)
+            catch
+              _ -> nil
+            after
+              send(test_pid, :done)
+            end
+          end)
+
+        # Wait for task to finish
+        receive do
+          :done -> nil
+        end
+
+        # Let logs flush
+        Process.sleep(100)
+      end)
+
+    [_, log_entry] =
+      logs
+      |> String.trim()
+      |> String.split("\n")
+      |> Enum.map(&decode_or_print_error/1)
+
+    assert %{
+             "error.message" => "boom",
+             "error.type" => "Elixir.RuntimeError",
+             "error.stack_trace" => "** (RuntimeError) boom" <> _,
+             "message" => message
+           } = log_entry
+
+    assert message =~ ~r/Task #PID<\d+.\d+.\d+> started from #{inspect(test_pid)} terminating/
+  end
+
   test "passing options to encoder" do
     formatter = {Elastic, encoder_opts: [pretty: true]}
     :logger.update_handler_config(:default, :formatter, formatter)

test/logger_json/formatters/google_cloud_test.exs

@@ -454,7 +454,7 @@ defmodule LoggerJSON.Formatters.GoogleCloudTest do
     assert %{
              "@type" => "type.googleapis.com/google.devtools.clouderrorreporting.v1beta1.ReportedErrorEvent",
              "message" => message,
-             "stack_trace" => "** ({{%RuntimeError{message: \"boom\"}" <> _,
+             "stack_trace" => "** (RuntimeError) boom" <> _,
              "serviceContext" => %{"service" => "nonode@nohost"}
            } = log_entry