Log code coverage with Codecov

bcoconni · bcoconni · commit e8159ab2cb13 · 2022-09-17T12:58:15.000+02:00
diff --git a/.github/workflows/cpp-python-build.yml b/.github/workflows/cpp-python-build.yml
@@ -649,6 +649,37 @@ jobs:
           name: ${{ matrix.os }}-Wheels.binaries
           path: ./wheelhouse/*.whl
 
+  Codecov:
+    name: Code coverage
+    needs: Linux
+    if: ${{ !startsWith(github.ref, 'refs/tags/') }}
+    runs-on: ubuntu-latest
+    steps:
+      - name: Install Ubuntu packages
+        run: |
+          sudo apt-get update
+          sudo apt-get install cxxtest lcov
+      - name: Checkout JSBSim
+        uses: actions/checkout@v3
+      - name: Configure JSBSim
+        run: |
+          mkdir build && cd build
+          cmake -DENABLE_COVERAGE=ON -DBUILD_PYTHON_MODULE=OFF ..
+      - name: Build JSBSim
+        working-directory: build
+        run: make -j2
+      - name: Run JSBSim tests
+        working-directory: build
+        run: ctest -R Test1 --output-on-failure
+      - name: Generate coverage report
+        working-directory: build
+        run: make lcov
+      - name: Upload to Codecov
+        uses: codecov/codecov-action@v3
+        with:
+          working-directory: build/lcov/data/capture
+          files: all_targets.info
+
   Rolling-Release:
     needs: [Python-Wheels, Test-Build-PyPackage-From-Source, Windows-MinGW32, Windows-installer]
     name: Deploy Rolling Release
@@ -804,19 +835,19 @@ jobs:
       - name: Install Ubuntu packages
         run: |
           sudo apt-get update
-          sudo apt-get install doxygen graphviz cxxtest lcov
+          sudo apt-get install doxygen graphviz
       - name: Set up Python 3.7
         uses: actions/setup-python@v4
         with:
           python-version: '3.7'
       - name: Install Python packages
-        run: pip install -U numpy sphinx cython 'setuptools>=60.0.0'
+        run: pip install -U numpy sphinx
       - name: Checkout JSBSim
         uses: actions/checkout@v3
       - name: Configure JSBSim
         run: |
           mkdir build && cd build
-          cmake -DCMAKE_C_FLAGS_DEBUG="--coverage" -DCMAKE_CXX_FLAGS_DEBUG="--coverage" -DCMAKE_BUILD_TYPE=Debug ..
+          cmake -DBUILD_PYTHON_MODULE=OFF ..
       - name: Download Python wheels
         uses: actions/download-artifact@v3
         with:
@@ -828,16 +859,6 @@ jobs:
           pip install jsbsim --no-index -f .
           touch documentation/html/.nojekyll
           sphinx-build -b html documentation documentation/html/python
-      - name: Build JSBSim
-        working-directory: build
-        run: make -j2
-      - name: Unit tests coverage
-        working-directory: build
-        run: |
-          ctest -R Test1 --output-on-failure
-          lcov -d . -c -o tmp.info
-          lcov -r tmp.info /usr/include/c++/\* /usr/include/cxxtest/\* \*/tests/unit_tests/\* -o coverage.info
-          genhtml -o documentation/html/coverage -t "JSBSim unit tests" coverage.info
       - name: Publish docs to GitHub Pages
         uses: crazy-max/ghaction-github-pages@v3
         with:
diff --git a/CMakeLists.txt b/CMakeLists.txt
@@ -34,6 +34,8 @@ find_package(PkgConfig)
 # Build JSBSim libs and exec                                                   #
 ################################################################################
 
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/tests/unit_tests/CMakeModules)
+find_package(codecov)
 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 add_subdirectory(src)
 
@@ -114,6 +116,11 @@ if (CXXTEST_FOUND)
   include_directories(${PROJECT_SOURCE_DIR}/src)
   enable_testing()
   add_subdirectory(tests/unit_tests)
+  list(APPEND LCOV_REMOVE_PATTERNS "'*/JSBSim.cpp'")
+  list(APPEND LCOV_REMOVE_PATTERNS "'*/GeographicLib/*'")
+  list(APPEND LCOV_REMOVE_PATTERNS "'*/simgear/*'")
+  list(APPEND LCOV_REMOVE_PATTERNS "'*/unit_tests/*'")
+  coverage_evaluate()
 endif(CXXTEST_FOUND)
 
 ################################################################################
diff --git a/python/CMakeLists.txt b/python/CMakeLists.txt
@@ -67,13 +67,9 @@ file(COPY ${PROJECT_SOURCE_DIR}/scripts DESTINATION ${CMAKE_CURRENT_BINARY_DIR}/
 
 # Copy each source file
 foreach(OBJECT ${libJSBSim_SOURCE_FILES})
-  string(SUBSTRING ${OBJECT} 0 17 HEADER)
-  if (${HEADER} STREQUAL "$<TARGET_OBJECTS:")
-    string(LENGTH ${OBJECT} OBJECT_LENGTH)
-    math(EXPR TARGET_LENGTH "${OBJECT_LENGTH}-18")
-    string(SUBSTRING ${OBJECT} 17 ${TARGET_LENGTH} TARGET)
-    get_target_property(TARGET_SOURCE_FILES ${TARGET} SOURCES)
-    get_target_property(TARGET_SOURCE_DIRECTORY ${TARGET} TARGET_DIRECTORY)
+  if(${OBJECT} MATCHES "TARGET_OBJECTS:([^ >]+)")
+    get_target_property(TARGET_SOURCE_FILES ${CMAKE_MATCH_1} SOURCES)
+    get_target_property(TARGET_SOURCE_DIRECTORY ${CMAKE_MATCH_1} TARGET_DIRECTORY)
     file(RELATIVE_PATH TARGET_PATH ${PROJECT_SOURCE_DIR} ${TARGET_SOURCE_DIRECTORY})
     file(MAKE_DIRECTORY ${TARGET_PATH})
     foreach(_FILE ${TARGET_SOURCE_FILES})
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
@@ -64,6 +64,7 @@ add_library(libJSBSim ${HEADERS} ${SOURCES}
   $<TARGET_OBJECTS:Simgear>
   $<TARGET_OBJECTS:GeographicLib>
   )
+add_coverage(libJSBSim)
 
 if(EXPAT_FOUND)
   include_directories(${EXPAT_INCLUDE_DIRS})
@@ -87,12 +88,8 @@ set(JSBSIM_MSVC_COMPILE_DEFINITIONS ${MSVC_COMPILE_DEFINITIONS} PARENT_SCOPE)
 get_target_property(libJSBSim_SOURCE_FILES libJSBSim SOURCES)
 
 foreach(OBJECT ${libJSBSim_SOURCE_FILES})
-  string(SUBSTRING ${OBJECT} 0 17 HEADER)
-  if (${HEADER} STREQUAL "$<TARGET_OBJECTS:")
-    string(LENGTH ${OBJECT} OBJECT_LENGTH)
-    math(EXPR TARGET_LENGTH "${OBJECT_LENGTH}-18")
-    string(SUBSTRING ${OBJECT} 17 ${TARGET_LENGTH} TARGET_OBJECT)
-    list(APPEND TARGET_OBJECTS_LIST ${TARGET_OBJECT})
+	if (${OBJECT} MATCHES "TARGET_OBJECTS:([^ >]+)")
+    list(APPEND TARGET_OBJECTS_LIST ${CMAKE_MATCH_1})
   endif()
 endforeach(OBJECT)
 
@@ -168,6 +165,8 @@ endif()
 
 add_executable(JSBSim JSBSim.cpp)
 target_link_libraries(JSBSim libJSBSim)
+# Add JSBSim to the coverage analysis to avoid linking errors
+add_coverage(JSBSim)
 
 if(MSVC AND BUILD_SHARED_LIBS)
   # Under Windows, during the linking process, executables must have a
diff --git a/src/initialization/CMakeLists.txt b/src/initialization/CMakeLists.txt
@@ -11,6 +11,7 @@ set(HEADERS FGInitialCondition.h
 add_library(Init OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(Init PROPERTIES TARGET_DIRECTORY
                            ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(Init)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/initialization
                          COMPONENT devel)
diff --git a/src/input_output/CMakeLists.txt b/src/input_output/CMakeLists.txt
@@ -44,5 +44,7 @@ set_target_properties(InputOutput PROPERTIES TARGET_DIRECTORY
 # See https://docs.microsoft.com/fr-fr/windows/win32/winprog/using-the-windows-headers#setting-winver-or-_win32_winnt
 target_compile_definitions(InputOutput PRIVATE $<$<BOOL:${MINGW}>:_WIN32_WINNT=0x600>)  # Windows Vista/Windows Server 2008
 
+add_coverage(InputOutput)
+
 install(FILES ${HEADERS} DESTINATION include/JSBSim/input_output
                          COMPONENT devel)
diff --git a/src/math/CMakeLists.txt b/src/math/CMakeLists.txt
@@ -33,5 +33,6 @@ set(HEADERS FGColumnVector3.h
 add_library(Math OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(Math PROPERTIES TARGET_DIRECTORY
                            ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(Math)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/math COMPONENT devel)
diff --git a/src/models/CMakeLists.txt b/src/models/CMakeLists.txt
@@ -48,5 +48,6 @@ set(HEADERS FGAerodynamics.h
 add_library(Models OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(Models PROPERTIES TARGET_DIRECTORY
                              ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(Models)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/models COMPONENT devel)
diff --git a/src/models/atmosphere/CMakeLists.txt b/src/models/atmosphere/CMakeLists.txt
@@ -12,6 +12,7 @@ set(HEADERS FGMSIS.h
 add_library(Atmosphere OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(Atmosphere PROPERTIES TARGET_DIRECTORY
                                  ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(Atmosphere)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/models/atmosphere
                          COMPONENT devel)
diff --git a/src/models/flight_control/CMakeLists.txt b/src/models/flight_control/CMakeLists.txt
@@ -40,6 +40,7 @@ set(HEADERS FGDeadBand.h
 add_library(FlightControl OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(FlightControl PROPERTIES TARGET_DIRECTORY
                                     ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(FlightControl)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/models/flight_control
                          COMPONENT devel)
diff --git a/src/models/propulsion/CMakeLists.txt b/src/models/propulsion/CMakeLists.txt
@@ -31,6 +31,7 @@ set(HEADERS FGElectric.h
 add_library(Propulsion OBJECT ${HEADERS} ${SOURCES})
 set_target_properties(Propulsion PROPERTIES TARGET_DIRECTORY
                                  ${CMAKE_CURRENT_SOURCE_DIR})
+add_coverage(Propulsion)
 
 install(FILES ${HEADERS} DESTINATION include/JSBSim/models/propulsion
                          COMPONENT devel)
diff --git a/tests/unit_tests/CMakeLists.txt b/tests/unit_tests/CMakeLists.txt
@@ -21,6 +21,7 @@ set(UNIT_TESTS FGColumnVector3Test
 foreach(test ${UNIT_TESTS})
   cxxtest_add_test(${test}1 ${test}.cpp ${CMAKE_CURRENT_SOURCE_DIR}/${test}.h)
   target_link_libraries(${test}1 libJSBSim)
+  add_coverage(${test}1)
 endforeach()
 
 # Windows needs the DLL to be copied locally for unit tests to run.
diff --git a/tests/unit_tests/CMakeModules/FindGcov.cmake b/tests/unit_tests/CMakeModules/FindGcov.cmake
@@ -0,0 +1,162 @@
+# This file is part of CMake-codecov.
+#
+# Copyright (c)
+#   2015-2020 RWTH Aachen University, Federal Republic of Germany
+#
+# See the LICENSE file in the package base directory for details
+#
+# Written by Alexander Haase, alexander.haase@rwth-aachen.de
+#
+
+
+# include required Modules
+include(FindPackageHandleStandardArgs)
+
+
+# Search for gcov binary.
+set(CMAKE_REQUIRED_QUIET_SAVE ${CMAKE_REQUIRED_QUIET})
+set(CMAKE_REQUIRED_QUIET ${codecov_FIND_QUIETLY})
+
+get_property(ENABLED_LANGUAGES GLOBAL PROPERTY ENABLED_LANGUAGES)
+foreach (LANG ${ENABLED_LANGUAGES})
+	# Gcov evaluation is dependent on the used compiler. Check gcov support for
+	# each compiler that is used. If gcov binary was already found for this
+	# compiler, do not try to find it again.
+	if (NOT GCOV_${CMAKE_${LANG}_COMPILER_ID}_BIN)
+		get_filename_component(COMPILER_PATH "${CMAKE_${LANG}_COMPILER}" PATH)
+
+		if ("${CMAKE_${LANG}_COMPILER_ID}" STREQUAL "GNU")
+			# Some distributions like OSX (homebrew) ship gcov with the compiler
+			# version appended as gcov-x. To find this binary we'll build the
+			# suggested binary name with the compiler version.
+			string(REGEX MATCH "^[0-9]+" GCC_VERSION
+				"${CMAKE_${LANG}_COMPILER_VERSION}")
+
+			find_program(GCOV_BIN NAMES gcov-${GCC_VERSION} gcov
+				HINTS ${COMPILER_PATH})
+
+		elseif ("${CMAKE_${LANG}_COMPILER_ID}" MATCHES "^(Apple)?Clang$")
+			# Some distributions like Debian ship llvm-cov with the compiler
+			# version appended as llvm-cov-x.y. To find this binary we'll build
+			# the suggested binary name with the compiler version.
+			string(REGEX MATCH "^[0-9]+.[0-9]+" LLVM_VERSION
+				"${CMAKE_${LANG}_COMPILER_VERSION}")
+
+			# llvm-cov prior version 3.5 seems to be not working with coverage
+			# evaluation tools, but these versions are compatible with the gcc
+			# gcov tool.
+			if(LLVM_VERSION VERSION_GREATER 3.4)
+				find_program(LLVM_COV_BIN NAMES "llvm-cov-${LLVM_VERSION}"
+					"llvm-cov" HINTS ${COMPILER_PATH})
+				mark_as_advanced(LLVM_COV_BIN)
+
+				if (LLVM_COV_BIN)
+					find_program(LLVM_COV_WRAPPER "llvm-cov-wrapper" PATHS
+						${CMAKE_MODULE_PATH})
+					if (LLVM_COV_WRAPPER)
+						set(GCOV_BIN "${LLVM_COV_WRAPPER}" CACHE FILEPATH "")
+
+						# set additional parameters
+						set(GCOV_${CMAKE_${LANG}_COMPILER_ID}_ENV
+							"LLVM_COV_BIN=${LLVM_COV_BIN}" CACHE STRING
+							"Environment variables for llvm-cov-wrapper.")
+						mark_as_advanced(GCOV_${CMAKE_${LANG}_COMPILER_ID}_ENV)
+					endif ()
+				endif ()
+			endif ()
+
+			if (NOT GCOV_BIN)
+				# Fall back to gcov binary if llvm-cov was not found or is
+				# incompatible. This is the default on OSX, but may crash on
+				# recent Linux versions.
+				find_program(GCOV_BIN gcov HINTS ${COMPILER_PATH})
+			endif ()
+		endif ()
+
+
+		if (GCOV_BIN)
+			set(GCOV_${CMAKE_${LANG}_COMPILER_ID}_BIN "${GCOV_BIN}" CACHE STRING
+				"${LANG} gcov binary.")
+
+			if (NOT CMAKE_REQUIRED_QUIET)
+				message("-- Found gcov evaluation for "
+				"${CMAKE_${LANG}_COMPILER_ID}: ${GCOV_BIN}")
+			endif()
+
+			unset(GCOV_BIN CACHE)
+		endif ()
+	endif ()
+endforeach ()
+
+
+
+
+# Add a new global target for all gcov targets. This target could be used to
+# generate the gcov files for the whole project instead of calling <TARGET>-gcov
+# for each target.
+if (NOT TARGET gcov)
+	add_custom_target(gcov)
+endif (NOT TARGET gcov)
+
+
+
+# This function will add gcov evaluation for target <TNAME>. Only sources of
+# this target will be evaluated and no dependencies will be added. It will call
+# Gcov on any source file of <TNAME> once and store the gcov file in the same
+# directory.
+function (add_gcov_target TNAME)
+	get_target_property(TBIN_DIR ${TNAME} BINARY_DIR)
+	set(TDIR ${TBIN_DIR}/CMakeFiles/${TNAME}.dir)
+
+	# We don't have to check, if the target has support for coverage, thus this
+	# will be checked by add_coverage_target in Findcoverage.cmake. Instead we
+	# have to determine which gcov binary to use.
+	get_target_property(TSOURCES ${TNAME} SOURCES)
+	set(SOURCES "")
+	set(TCOMPILER "")
+	foreach (FILE ${TSOURCES})
+		codecov_path_of_source(${FILE} FILE)
+		if (NOT "${FILE}" STREQUAL "")
+			codecov_lang_of_source(${FILE} LANG)
+			if (NOT "${LANG}" STREQUAL "")
+				list(APPEND SOURCES "${FILE}")
+				set(TCOMPILER ${CMAKE_${LANG}_COMPILER_ID})
+			endif ()
+		endif ()
+	endforeach ()
+
+	# If no gcov binary was found, coverage data can't be evaluated.
+	if (NOT GCOV_${TCOMPILER}_BIN)
+		message(WARNING "No coverage evaluation binary found for ${TCOMPILER}.")
+		return()
+	endif ()
+
+	set(GCOV_BIN "${GCOV_${TCOMPILER}_BIN}")
+	set(GCOV_ENV "${GCOV_${TCOMPILER}_ENV}")
+
+
+	set(BUFFER "")
+	set(NULL_DEVICE "/dev/null")
+	if(WIN32)
+		set(NULL_DEVICE "NUL")
+	endif()
+	foreach(FILE ${SOURCES})
+		get_filename_component(FILE_PATH "${TDIR}/${FILE}" PATH)
+
+		# call gcov
+		add_custom_command(OUTPUT ${TDIR}/${FILE}.gcov
+			COMMAND ${GCOV_ENV} ${GCOV_BIN} -p ${TDIR}/${FILE}.gcno > ${NULL_DEVICE}
+			DEPENDS ${TNAME} ${TDIR}/${FILE}.gcno
+			WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+		)
+
+		list(APPEND BUFFER ${TDIR}/${FILE}.gcov)
+	endforeach()
+
+
+	# add target for gcov evaluation of <TNAME>
+	add_custom_target(${TNAME}-gcov DEPENDS ${BUFFER})
+
+	# add evaluation target to the global gcov target.
+	add_dependencies(gcov ${TNAME}-gcov)
+endfunction (add_gcov_target)
diff --git a/tests/unit_tests/CMakeModules/FindLcov.cmake b/tests/unit_tests/CMakeModules/FindLcov.cmake
diff --git a/tests/unit_tests/CMakeModules/Findcodecov.cmake b/tests/unit_tests/CMakeModules/Findcodecov.cmake
diff --git a/tests/unit_tests/CMakeModules/LICENSE b/tests/unit_tests/CMakeModules/LICENSE
